[重要通告]如您遇疑難雜癥,本站支持知識(shí)付費(fèi)業(yè)務(wù),掃右邊二維碼加博主微信,可節(jié)省您寶貴時(shí)間哦!

大家玩Mysql8都應(yīng)該知道，Windows系統(tǒng)下的，mysql8 裝包是MSI文件，自動(dòng)把程序安裝到了C盤，沒(méi)注意有自定義選項(xiàng)，更改安裝位置的配置可以修改。

故自行寫了一個(gè)腳本，用來(lái)安裝mysql8壓縮包。可以將 mysql8及其Data目錄安裝到C盤以外的位置；

自動(dòng)配置Windows系統(tǒng)下MYSQL8壓縮包bat腳本如下：

@echo off
:: 設(shè)置將要生成的文件的路徑
set base_dir=%cd%
set data_dir=%base_dir%\Data
set myini_file=%base_dir%\my.ini
set Uploads_dir=%base_dir%\Uploads

:: 設(shè)置一些變量默認(rèn)值
set agree=Y
set data_is_empty=0
set is_gen_start_file=N
set is_install_service=N
set is_clear_datadir=N
set is_add_path=N

:: 判斷腳本當(dāng)前所在的位置
%cd%/bin/mysql.exe --version >nul
if not %errorlevel%==0 (
echo 腳本執(zhí)行結(jié)束，請(qǐng)將此腳本移動(dòng)到mysql程序的根目錄下再執(zhí)行（跟bin目錄同一級(jí)目錄）
goto end
)

:: 打印程序安裝說(shuō)明
echo 使用說(shuō)明：
echo 使用此腳本安裝mysql時(shí)，會(huì)將保存數(shù)據(jù)的Data目錄以及my.ini文件放在MySQL程序的根目錄下：
echo %base_dir%
echo 可以修改此腳本的路徑變量進(jìn)行重新指定路徑
set /p agree=如果同意，按任意鍵繼續(xù)，按q鍵退出：
if /i %agree%==Q (
echo 退出安裝
goto end
) else if /i not %agree%==Q (
echo 腳本開始安裝mysql.......
)

:: 生成my.ini配置文件
if not exist %myini_file% (
echo [mysqld] >> %myini_file%
echo basedir=%cd% >> %myini_file%
echo datadir=%data_dir% >> %myini_file%
echo secure-file-priv=%cd%\Uploads >> %myini_file%
echo 生成my.ini文件：%myini_file%
) else (
echo %myini_file%文件已存在，即將使用該配置文件
)

:: 創(chuàng)建 Uploads 目錄
if not exist %Uploads_dir% (
md %Uploads_dir%
echo 創(chuàng)建Uploads目錄：%Uploads_dir%
) else (
echo %Uploads_dir%目錄已存在，跳過(guò)創(chuàng)建
)

:: 創(chuàng)建 Data 目錄
:md_data_dir
if not exist %data_dir% (
md %data_dir%
echo 創(chuàng)建Data目錄：%data_dir%
:: 創(chuàng)建了目錄后，直接進(jìn)行安裝
goto initialize_data
) else (
goto data_dir_check
)

:: 如果Data目錄已存在，則檢查Data目錄是否為空
:data_dir_check
for /f "tokens=* delims=" %%i in ('dir /b /a "%data_dir%"') do (
set /p is_clear_datadir=%data_dir%目錄已存在，并且目錄不為空，是否清空Data目錄（N不清空，Y清空）:
goto clear_datadir
)

if %data_is_empty%==0 (
echo %data_dir%為空，即將初始化Data目錄進(jìn)行安裝
goto initialize_data
)

:clear_datadir
if /i %is_clear_datadir%==Y (
echo 正在清空%data_dir%
rd /s /q %data_dir%
goto :md_data_dir
) else if /i %is_clear_datadir%==N (
echo 跳過(guò)清空Data目錄，即將進(jìn)行不初化安裝
goto :install_service
) else (
goto :data_dir_check
)

:initialize_data
echo 正在初始化Mysql....
%base_dir%/bin/mysqld.exe --defaults-file=%myini_file% --initialize-insecure --console
echo MySQL初始化完畢！
echo ===================================================
echo 注意！root用戶的密碼為空！
echo ===================================================

:need_install_service
set /p is_install_service=是否需要將MySQL設(shè)置成為windows系統(tǒng)服務(wù)(需要管理員身份)（Y/N，默認(rèn)N）:
if /i %is_install_service%==Y (
goto install_service
) else if /i %is_install_service%==N (
echo 已選擇無(wú)須將MySQL設(shè)置為系統(tǒng)服務(wù)
goto gen_start_file
) else (
goto need_install_service
)

:install_service
echo 正在將檢查windows服務(wù)......
:: sc query type^= all ^| findstr /i "SERVICE_NAME"
for /F "tokens=2" %%i in (' sc query type^= service state^= all ^| findstr /i "MySQL" ^| findstr /i "SERVICE_NAME" ') do (
for /F "tokens=* delims=" %%s in ('sc qc %%i ^| findstr /i "BINARY_PATH_NAME"' ) do (
echo %%s | find /i "%base_dir%" > NUL && echo MySQL已經(jīng)是Windows系統(tǒng)服務(wù) & goto gen_start_file
)
)
echo 正在將MySQL注冊(cè)成為Windows系統(tǒng)服務(wù)......
%base_dir%/bin/mysqld.exe --install MySQL8 --defaults-file=%myini_file%
sc config MySQL8 start=demand

:gen_start_file
set /p is_gen_start_file=是否需要在bin目錄下生成一鍵啟動(dòng)腳本mysqld_start(Y/N，默認(rèn)N)：
if /i %is_gen_start_file%==Y (
echo mysqld.exe --defaults-file=%myini_file% --console > %base_dir%/bin/mysqld_start.bat
) else (
echo 已選擇不生成一鍵啟動(dòng)腳本。
)

:: 添加到用戶級(jí)的環(huán)境變量
set /p is_add_path=是否需要將MySQL添加到環(huán)境變量(Y/N，默認(rèn)N):
if /i %is_add_path%==N (
echo 已跳過(guò)添加MySQL到環(huán)境變量
) else (
set path | find /i "%base_dir%\bin" > nul || setx PATH "%PATH%;%base_dir%\bin"
echo 已添加環(huán)境變量
)

:end
echo 腳本執(zhí)行完畢！！！

按照以上的操作就可以處理Windows系統(tǒng)下的mysql8的部署，其實(shí)想自己手動(dòng)一點(diǎn)點(diǎn)的處理也是可以的！

Windows部署mysql8腳本txt文件：? Win下mysql8腳本

Windows系統(tǒng)下安裝以及配置apache、mysql、PHP全程詳細(xì)圖解教程

問(wèn)題未解決？付費(fèi)解決問(wèn)題加Q或微信 2589053300 (即Q號(hào)又微信號(hào))右上方掃一掃可加博主微信

所寫所說(shuō)，是心之所感，思之所悟，行之所得；文當(dāng)無(wú)敷衍，落筆求簡(jiǎn)潔。 以所舍，求所獲；有所依，方所成！