[重要通告]如您遇疑難雜癥,本站支持知識付費業務,掃右邊二維碼加博主微信,可節省您寶貴時間哦!

@echo off
::\\\\\\\\\開始設置\\\\\\\\\
::-------------------------------
::設置FTP服務器地址
set host=www.xxxxxx.com
::設置FTP用戶名
set user=username
::設置FTP密碼
set password=password
::設置遠程路徑,注意斜線方向
set remotepath=/www/
::設置要備份的文件名稱
set bakfile=search.db
::設置備份到哪里<本地路徑>,為讓程序正常運行,請先建立該文件夾
set bakpath=F:\bak
::-------------------------------
::\\\\\\\\\結束設置\\\\\\\\\

::\\\\\\\\\\\不熟悉P處理的請務修改以下內容\\\\\\\\\\\

::\\\\生成FTP命令腳本
:index
cls
title 正在生成FTP備份腳本
echo ╔───────────────────────╗
echo │ 正在生成FTP備份腳本 │
echo ╚───────────────────────╝
echo open %host%>"%temp%\ftpbak_script.txt"
echo %user%>>"%temp%\ftpbak_script.txt"
echo %password%>>"%temp%\ftpbak_script.txt"
echo ascii>>"%temp%\ftpbak_script.txt"
echo cd %remotepath%>>"%temp%\ftpbak_script.txt"
echo prompt>>"%temp%\ftpbak_script.txt"
echo lcd %bakpath%>>"%temp%\ftpbak_script.txt"
echo mget %bakfile%>>"%temp%\ftpbak_script.txt"
echo bye>>"%temp%\ftpbak_script.txt"
goto start

::\\\\運行FTP命令腳本
:start
cls
title 數據庫備份
echo ╔───────────────────╗
echo │ 數據庫備份日志 │
echo ╚───────────────────╝
echo -------------------------------------------------------------------------
echo 需要備份的文件:%host%%remotepath%%bakfile%
echo 正在將其備份到:%bakpath%
echo -------------------------------------------------------------------------
echo 需要的時間視您的網絡情況以及要備份的文件大小而定,請耐心等待
echo.
echo 備份過程中,請不要關閉本程序,以免備份文件出錯!
ftp -s:"%temp%\ftpbak_script.txt" >nul

cls
::\\\\開始寫入日志
echo ╔───────────────────╗ >>"%userprofile%\桌面\備份日志.txt"
echo │ 數據庫備份日志 │ >>"%userprofile%\桌面\備份日志.txt"
echo ╚───────────────────╝ >>"%userprofile%\桌面\備份日志.txt"
echo ---------------------------------------->>"%userprofile%\桌面\備份日志.txt"
echo 備份日期:%DATE% %TIME:~0,2%:%TIME:~3,2%:%TIME:~6,2% >>"%userprofile%\桌面\備份日志.txt"
echo 備份文件:%host%%remotepath%%bakfile% >>"%userprofile%\桌面\備份日志.txt"
echo 備份路徑:%bakpath% >>"%userprofile%\桌面\備份日志.txt"
echo ---------------------------------------->>"%userprofile%\桌面\備份日志.txt"
echo ---------------------------------------->>"%userprofile%\桌面\備份日志.txt"
exit

問題未解決？付費解決問題加Q或微信 2589053300 (即Q號又微信號)右上方掃一掃可加博主微信

所寫所說，是心之所感，思之所悟，行之所得；文當無敷衍，落筆求簡潔。 以所舍，求所獲；有所依，方所成！